aswi2021virtual-surreality-gitlab/deltarobot/glsl/shader.vert @ 9360266c

// Matice projekce.
uniform mat4 un_Projection;
// Pozice svetla.
uniform vec3 un_Light;
// Model-view matice pro kazdy graficky prvek (az na zdi, pro ty se matice shoduji
// s matici trajektorie).
uniform mat4 un_ModelView[5];
// Normalova matice pro kazdy graficky prvek (az na zdi).
uniform mat3 un_Normal[5];
// Barvy pro kazdy graficky prvek (az na zdi, u tech je barva urcena texturou).
uniform vec4 un_Color[5];

// Souradnice vrcholu.
attribute vec3 vertex;
// Normala pridelena k danemu vrcholu.
attribute vec3 normal;
// K jakemu grafickemu prvku vrchol patri.
attribute float group;

// Typ grafickeho prvku, ktery je sdilen s FRAGMENT casti shader programu.
varying float v_Group;
// Intezita svetla pro dany vrchol.
varying float v_Light;
// Barva daneho vrcholu.
varying vec4 v_Color;
// Jaka UV souradnice textury odpovida danemu vrcholu (pouze u group >= 4, coz
// jsou zdi).
varying vec2 v_Coord;

// Pri kazdem prekresleni se zavola pro kazdy vrchol.
void main()
{
    v_Group = group;
    if (v_Group >= 5.0)
    {
        int corner = int(v_Group) - 5; // O jaky roh textury jde.
        v_Coord = vec2(corner == 2 || corner == 3, corner == 1 || corner == 3);
        v_Group = 5.0; // Pro vsechny zdi stejna pravidla (az na barvy).
    }
    
    // a mod b = a - (b * floor(a/b))
    int index = int(v_Group) - (5 * int(floor(v_Group / 5.0))); // 5 = zed - bez jakychkoli uprav, stejne jako 0 = trajektorie.
    v_Light = max(dot(normalize(un_Normal[index] * normal), normalize(un_Light - vertex)), 0.0);
    v_Color = un_Color[index];
    
    // Vysledna pozice (pixel).
    gl_Position = un_Projection * un_ModelView[index] * vec4(vertex, 1.0);
}