aswi2021tri-musketyri-gitlab/Client/Client/Assets/Scripts/Shaders/MapUnderlay.shader @ 755c25f3

// Based on Unity's Unlit/Transparent

Shader "Unlit/MapUnderlay"
{
    Properties
    {
        _MainTex("Texture", 2D) = "white" {}
        _Min("Min", Range(0.0, 1.0)) = 0.0
        _Max("Max", Range(0.0, 1.0)) = 0.25
        _Color("Color", Color) = (0,0,0,0)
    }
        SubShader{
         Tags 
            {
                "Queue" = "Transparent" 
                "IgnoreProjector" = "True" 
                "RenderType" = "Transparent"
            }

         LOD 100

         ZWrite Off
         Blend SrcAlpha OneMinusSrcAlpha

         Pass {
             CGPROGRAM
                 #pragma vertex vert
                 #pragma fragment frag
                 #include "UnityCG.cginc"

                 struct appdata_t {
                     float4 vertex : POSITION;
                     float2 texcoord : TEXCOORD0;
                 };

                 struct v2f {
                     float4 vertex : SV_POSITION;
                     half2 texcoord : TEXCOORD0;
                     UNITY_FOG_COORDS(1)
                 };

                 sampler2D _MainTex;
                 float4 _MainTex_ST;
                 float _Min;
                 float _Max;
                 float4 _Color;

                 v2f vert(appdata_t v)
                 {
                     v2f o;
                     o.vertex = UnityObjectToClipPos(v.vertex);
                     o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                     return o;
                 }

                 fixed4 frag(v2f i) : SV_Target
                 {
                     fixed4 sampled = tex2D(_MainTex, i.texcoord);

                     float bw = (0.3f * sampled.r) + (0.59f * sampled.g) + (0.11f * sampled.b);
                     float clamped = _Min + (_Max - _Min) * bw;

                     sampled.rgb = clamped;

                     return sampled;
                 }
             ENDCG
         }
    }
}