aswi2021jmsd-gitlab/robot_tests/user_stories.robot @ b0917325

*** Settings ***
Library   Browser
Test Setup     Setup Homepage
Test Teardown  Delete Root Certificate Authority Teardown

*** Variables ***
${url}  http://localhost:5000
${root_ca_common_name}   Root CA
${inter_ca_common_name}  Inter CA
${end_cert_common_name}  Foo Certificate
${no_certificate_found}  No certificate found
${common_name_field}    xpath=//input[@id='subject_CN']
${created_certificate_link}    xpath=//table//td[1]/a
${delete_button}    xpath=//button[contains(@class, 'certificate-control') and text()="Delete"]
${delete_button_modal}    xpath=//div[@id="deleteModal"]//button[text()="Delete"]
${table_rows}   xpath=//div[@id="certificateListingPage"]//table/tbody/tr
${table_rows_count}   xpath=count(//div[@id="certificateListingPage"]//table/tbody/tr)
${create_cert_select}   xpath=//select[@id="CA"]
${revocation_reason_select}   xpath=//select[@id="reasonSelect"]
${revoke_button_modal}   xpath=//div[@id="revokeModal"]//button[text() = "Revoke"]
${certificate_status_span}   xpath=//table//td[2]/h5/span

*** Test Cases ***
User Can Manage Certificate Authorities
    Page Title Is    Certificate Listing                                                        # FR 1.1 - root CA
    Certificate Table Is Empty
    Create Root Certificate Authority   ${root_ca_common_name}
    Page Title Is    Certificate Listing
    Certificate Table Has Number Of Entries     1
    Verify Certificate Is A Certificate Authority   ${root_ca_common_name}
    Create Intermediate Certificate Authority   ${root_ca_common_name}  ${inter_ca_common_name}     # FR 1.1 - inter CA
    Certificate Table Has Number Of Entries     2
    Verify Certificate Is A Certificate Authority   ${inter_ca_common_name}
    Open Certificate Detail   ${inter_ca_common_name}                                           # FR 1.3 - validity
    Page Title Is    Certificate Detailed View
    Certificate Status Is   Valid
    Revoke Certificate  keyCompromise                                                           # FR 1.2 - revocation
    Check Certificate Is Revoked
    Click Delete Button                                                                         # FR 1.3 - deletion
    Confirm Delete Dialog
    Page Title Is   Certificate Listing
    Certificate Table Has Number Of Entries     1
    First Certificate Table Entry Common Name Is     ${root_ca_common_name}

User Can Manage Certificates
    Page Title Is   Certificate Listing                                                         # root CA required
    Certificate Table Is Empty
    Create Root Certificate Authority   ${root_ca_common_name}
    Create Certificate  ${root_ca_common_name}  ${end_cert_common_name}                         # FR 2.1
    Certificate Table Has Number Of Entries     2
    Open Certificate Detail     ${end_cert_common_name}                                         # FR 2.3
    Certificate Status Is   Valid
    Revoke Certificate  keyCompromise                                                           # FR 2.2
    Check Certificate Is Revoked

*** Keywords ***
Delete Root Certificate Authority Teardown
    Setup Homepage
    Wait Until Network Is Idle
    Page Title Is    Certificate Listing
    Open Certificate Detail     ${root_ca_common_name}
    # deleting the root CA deletes all of it's children
    Click Delete Button
    Confirm Delete Dialog
    Wait Until Network Is Idle
    Certificate Table Is Empty

Create Root Certificate Authority
    [Arguments]    ${common_name}
    Click   "+"
    Wait Until Network Is Idle
    Page Title Is    Create Certificate
    Fill Common Name Field    ${common_name}
    Click   "Create certificate"
    Wait Until Network Is Idle
    Page Title Is    Certificate Listing

Create Intermediate Certificate Authority
    [Arguments]    ${issuer_common_name}   ${common_name}
    Click   "+"
    Wait Until Network Is Idle
    Page Title Is    Create Certificate
    Select Issuer   ${issuer_common_name}
    Fill Common Name Field    ${common_name}
    Check Checkbox  "CA"
    Click   "Create certificate"
    Wait Until Network Is Idle
    Page Title Is    Certificate Listing

Create Certificate
    [Arguments]    ${issuer_common_name}   ${common_name}
    Click   "+"
    Wait Until Network Is Idle
    Page Title Is    Create Certificate
    Select Issuer   ${issuer_common_name}
    Fill Common Name Field    ${common_name}
    Click   "Create certificate"
    Wait Until Network Is Idle
    Page Title Is    Certificate Listing

Open Certificate Detail
    [Arguments]     ${common_name}
    Click   xpath=//td/a[string() = "${common_name}"]
    Wait Until Network Is Idle

Revoke Certificate
    [Arguments]  ${reason}
    Click Revoke Button
    Select Revocation Reason    ${reason}
    Confirm Revoke Dialog
    Wait Until Network Is Idle

Verify Certificate Is A Certificate Authority
    [Arguments]     ${common_name}
    Open Certificate Detail     ${common_name}
    Wait Until Network Is Idle
    Get Checkbox State  xpath=//input[@id="isCA"]   ==  checked
    Go Back

Setup Homepage
    New Page    ${url}

Certificate Table Has Number Of Entries
    [Arguments]     ${number_of_entries}
    Get Element Count     ${table_rows}   ==  ${number_of_entries}

Certificate Table Is Empty
    Certificate Table Has Number Of Entries  1
    Get Text  ${table_rows}  ==  ${no_certificate_found}

Page Title Is
    [Arguments]     ${title}
    Get Text    h1    contains    ${title}

Fill Common Name Field
    [Arguments]     ${common_name}
    Fill Text   ${common_name_field}    ${common_name}

First Certificate Table Entry Common Name Is
    [Arguments]     ${common_name}
    Get Text    ${created_certificate_link}  ==     ${common_name}

Click First Certificate Table Entry
    Click   ${created_certificate_link}

Click Delete Button
    Click   ${delete_button}

Confirm Delete Dialog
    Click   ${delete_button_modal}

Select Issuer
    [Arguments]     ${issuer_name}
    Select Options By   ${create_cert_select}   Label   ${issuer_name}

Click Revoke Button
    Click   "Revoke"

Confirm Revoke Dialog
    Click   ${revoke_button_modal}

Select Revocation Reason
    [Arguments]     ${revocation_reason}
    Get Element     ${revocation_reason_select}
    Select Options By   ${revocation_reason_select}   Label   ${revocation_reason}

Revocation Success Messsage Is Shown
    Get Element     xpath=//div[@class="alert alert-success" and contains(string(), "Certificate revocation successful.")]

Certificate Status Is
    [Arguments]     ${certificate_status}
    Get Text    ${certificate_status_span}  ==  ${certificate_status}

Check Certificate Is Revoked
    Revocation Success Messsage Is Shown
    Certificate Status Is   Revoked