aswi2021jmsd-gitlab/robot_tests/sample.robot @ 7294a1db

*** Settings ***
Library   Browser

*** Variables ***
${url}  http://localhost:5000
${common_name}  Foo Bar CA
${common_name_field}    xpath=//input[@id='subject_CN']
${created_certificate_link}    xpath=//table//td[1]/a
${delete_button}    xpath=//button[contains(@class, 'certificate-control') and text()="Delete"]
${delete_button_modal}    xpath=//div[@id="deleteModal"]//button[text()="Delete"]
${table_rows}   xpath=//div[@id="certificateListingPage"]//table/tbody/tr


*** Test Cases ***
Example Test
    Setup Homepage
    Page Title Is    Certificate Listing
    Certificate Table Is Empty
    Click   "Create certificate"
    Page Title Is    Create Certificate
    Fill Common Name Field    ${common_name}
    Click   "Create certificate"
    Page Title Is    Certificate Listing
    Certificate Table Has Number Of Entries     1
    First Certificate Table Entry Common Name Is     ${common_name}
    Click First Certificate Table Entry
    Click Delete Button
    Confirm Delete Dialog
    Page Title Is    Certificate Listing
    Certificate Table Is Empty


*** Keywords ***
Setup Homepage
    New Page    ${url}

Certificate Table Has Number Of Entries
    [Arguments]     ${number_of_entries}
    Get Element Count     ${table_rows}   ==  ${number_of_entries}

Certificate Table Is Empty
    Certificate Table Has Number Of Entries     0

Page Title Is
    [Arguments]     ${title}
    Get Text    h1    contains    ${title}

Fill Common Name Field
    [Arguments]     ${common_name}
    Fill Text   ${common_name_field}    ${common_name}

First Certificate Table Entry Common Name Is
    [Arguments]     ${common_name}
    Get Text    ${created_certificate_link}  ==     ${common_name}

Click First Certificate Table Entry
    Click   ${created_certificate_link}

Click Delete Button
    Click   ${delete_button}

Confirm Delete Dialog
    Click   ${delete_button_modal}